Autoscrolling with AutoHotkey

This is the scrolling script I use.

#Requires AutoHotkey v2.0

scroll := MouseMovement(“MButton”, scrollfunc)

scrollfunc(xDelta, yDelta) {
static accumulator := 0
static threshold := 20 ; Adjust this value to control sensitivity (higher = less sensitive)

; Add the current movement to our accumulator
accumulator += yDelta

; Check if we’ve accumulated enough movement to trigger an arrow key
while (accumulator >= threshold) {
Send “{Up}”
accumulator -= threshold
}

while (accumulator <= -threshold) {
Send "{Down}"
accumulator += threshold ; Add because accumulator is negative
}
}

class MouseMovement {
__New(hk, callback) {
this.MD := MouseDelta(callback)
this.Toggle := 0

; Set up hotkeys for button down and up
Hotkey hk, hotkeyDownFunc, "On"
Hotkey hk " Up", hotkeyUpFunc, "On"

hotkeyDownFunc(*) {
if !this.Toggle {
this.Toggle := 1
; Start monitoring of mouse delta when button is pressed
this.MD.SetState(this.Toggle)
; Enable hook to block mouse movement
this.hook := MouseMovement.Hook(LowLevelMouseProc)
}
}

hotkeyUpFunc(*) {
if this.Toggle {
this.Toggle := 0
; Stop monitoring of mouse delta when button is released
this.MD.SetState(this.Toggle)
; Remove hook
this.hook := ""
}
}

LowLevelMouseProc(nCode, wParam, lParam) {
static WM_MOUSEMOVE := 0x200
if (wParam = WM_MOUSEMOVE) {
return 1 ; block mouse move
}
Return DllCall("CallNextHookEx", "Ptr", 0, "Int", nCode, "UInt", wParam, "Ptr", lParam)
}
}

; converted from https://www.autohotkey.com/boards/viewtopic.php?style=19&p=519818#p519818
class Hook {
__New(callback, isGlobal := true) {
static WH_MOUSE_LL := 14
this.pCallback := CallbackCreate(callback, 'Fast', 3)
this.hHook := DllCall('SetWindowsHookEx', 'Int', WH_MOUSE_LL, 'Ptr', this.pCallback,
'Ptr', !isGlobal ? 0 : DllCall('GetModuleHandle', 'UInt', 0, 'Ptr'),
'UInt', isGlobal ? 0 : DllCall('GetCurrentThreadId'), 'Ptr')
}

__Delete() {
DllCall('UnhookWindowsHookEx', 'Ptr', this.hHook)
CallbackFree(this.pCallback)
}
}
}

; converted from: https://www.autohotkey.com/boards/viewtopic.php?t=10159
Class MouseDelta {
State := 0
__New(callback) {
this.MouseMovedFn := this.MouseMoved.Bind(this)
this.Callback := callback
}

Start() {
static DevSize := 8 + A_PtrSize, RIDEV_INPUTSINK := 0x00000100
; Register mouse for WM_INPUT messages.
RAWINPUTDEVICE := Buffer(DevSize)
NumPut("UShort", 1, RAWINPUTDEVICE, 0)
NumPut("UShort", 2, RAWINPUTDEVICE, 2)
NumPut("Uint", RIDEV_INPUTSINK, RAWINPUTDEVICE, 4)
; WM_INPUT needs a hwnd to route to.
NumPut("Ptr", A_ScriptHwnd, RAWINPUTDEVICE, 8)
this.RAWINPUTDEVICE := RAWINPUTDEVICE
DllCall("RegisterRawInputDevices", "Ptr", RAWINPUTDEVICE, "UInt", 1, "UInt", DevSize)
OnMessage(0x00FF, this.MouseMovedFn)
this.State := 1
return this ; allow chaining
}

Stop() {
static RIDEV_REMOVE := 0x00000001
static DevSize := 8 + A_PtrSize
OnMessage(0x00FF, this.MouseMovedFn, 0)
RAWINPUTDEVICE := this.RAWINPUTDEVICE
NumPut("Uint", RIDEV_REMOVE, RAWINPUTDEVICE, 4)
DllCall("RegisterRawInputDevices", "Ptr", RAWINPUTDEVICE, "UInt", 1, "UInt", DevSize)
this.State := 0
return this ; allow chaining
}

SetState(state) {
if (state && !this.State)
this.Start()
else if (!state && this.State)
this.Stop()
return this ; allow chaining
}

Delete() {
this.Stop()
this.MouseMovedFn := ""
}

; Called when the mouse moved.
; Messages tend to contain small (+/- 1) movements, and happen frequently (~20ms)
MouseMoved(wParam, lParam, *) {
Critical
; RawInput statics
static DeviceSize := 2 * A_PtrSize, iSize := 0, sz := 0, pcbSize:=8+2*A_PtrSize, offsets := {x: (20+A_PtrSize*2), y: (24+A_PtrSize*2)}, uRawInput

; Find size of rawinput data – only needs to be run the first time.
if (!iSize) {
r := DllCall("GetRawInputData", "UInt", lParam, "UInt", 0x10000003, "Ptr", 0, "UInt*", &iSize, "UInt", 8 + (A_PtrSize * 2))
uRawInput := Buffer(iSize)
}
sz := iSize ; param gets overwritten with # of bytes output, so preserve iSize
; Get RawInput data
r := DllCall("GetRawInputData", "UInt", lParam, "UInt", 0x10000003, "Ptr", uRawInput, "UInt*", &sz, "UInt", 8 + (A_PtrSize * 2))

x := 0, y := 0 ; Ensure we always report a number for an axis. Needed?
x := NumGet(uRawInput, offsets.x, "Int")
y := NumGet(uRawInput, offsets.y, "Int")
Critical false
this.Callback.Call(x, y)
}
}